property pStageW -- the width of the stage
property pStageH -- the height of the stage
property plineLength -- the thickness of the lines drawn
property pRandom -- should lines be drawn with random thickness
property pMinSize -- the minimum size of each line
property pMaxSize -- the maximum size of each line

on prepareFrame me
  -- determine the width and height of the stage
  pStageW = getStageWidth(me)
  pStageH = getStageHeight(me)
end

--
-- This behavior draws randomly colored lines at the same
-- angle all over the stage using imaging Lingo. 
-- Place this in a frame script. No other sprites are needed
-- for it to work.
--
-- Ken Loge - http://diginoodles.com
--

on getPropertyDescriptionList me
  list = [:]
  addProp list, #plineLength, [#comment: "Line thickness:", #format: #integer, #default: 2, #range: [#min: 1, #max: 30]]
  addProp list, #pRandom, [#comment: "Randomize line thickness:", #format: #boolean, #default: FALSE]
  addProp list, #pMinSize, [#comment: "Minimum length of each line:", #format: #integer, #default: 5, #range: [#min: 0, #max: 30]]
  addProp list, #pMaxSize, [#comment: "Maximum length of each line:", #format: #integer, #default: 150, #range: [#min: 10, #max: 300]]
  return list
end

on exitFrame me
  -- get an image of the stage
  myImage = _movie.stage.image
  
  -- handle line thickness
  if pRandom = TRUE then
    strokeSize = random(plineLength)
  else
    strokeSize = plineLength
  end if
  
  -- get random line size
  lineLength = random(pMaxSize) + pMinSize
  
  -- get random line origin
  lineOrigin = point(random(getStageWidth(me) - pMinSize), random(getStageHeight(me) - pMinSize))
  
  -- set width limits for line
  if lineOrigin.locH > getStageWidth(me) - lineLength then
    lineOrigin.locH = getStageWidth(me) - lineLength * 2
  end if
  
  -- set height limits for line
  if lineOrigin.locV > getStageHeight(me) - lineLength then
    lineOrigin.locV = getStageHeight(me) - lineLength * 2
  end if
  
  -- set width and height of line
  lineWidth = lineOrigin.locH + lineLength
  lineHeight = lineOrigin.locV + lineLength
  
  -- draw the lines
  myImage.draw(point(lineOrigin.locH, lineOrigin.locV), point(lineWidth, lineHeight), [#shapeType: #line, #lineSize: strokeSize, #color: rgb(random(255), random(255), random(255))])
  
  _movie.go(_movie.frame)
end

-- get the width of the stage
on getStageWidth me
  return _movie.stage.rect[3] - _movie.stage.rect[1]
end

-- get the height of the stage
on getStageHeight me
  return _movie.stage.rect[4] - _movie.stage.rect[2]
end