property pBlurX, pBlurY, pQuality, pStrength, pStrengthPcnt -- blur vars
property pShadColorR, pShadColorG, pShadColorB -- shadow color
property pShadAlpha -- shadow alpha
property pHlColorR, pHlColorG, pHlColorB -- highlight color
property pHlAlpha -- highlight alpha
property pBevAngle -- bevel angle
property pBevDist -- bevel offset distance
property pKnockout, pInner

--
-- Drop onto a sprite for a Bevel visual effect on rollover.
-- Works only with Director 11.5 or newer
-- Sprite must have 32-bit color for the effect to display.
-- Ken Loge - http://diginoodles.com
--

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pBlurX, [#comment: "Horizontal Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pBlurY, [#comment: "Vertical Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pQuality, [#comment: "Blur Quality:", #format: #integer, #default: 2, #range: [#min: 0, #max: 15]]
  addProp list, #pStrength, [#comment: "Glow Contrast:", #format: #float, #default: 1.0, #range: [#min: 0, #max: 10]]
  addProp list, #pStrengthPcnt, [#comment: "Glow Strength:", #format: #integer, #default: 100, #range: [#min: 0, #max: 1000]]
  addProp list, #pShadColorR, [#comment: "Shadow Red Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pShadColorG, [#comment: "Shadow Green Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pShadColorB, [#comment: "Shadow Blue Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pShadAlpha, [#comment: "Shadow Alpha Transparency:", #format: #float, #default: 255.0, #range: [#min: 0, #max: 255]]
  addProp list, #pHlColorR, [#comment: "Highlight Red Color Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pHlColorG, [#comment: "Highlight Green Color Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pHlColorB, [#comment: "Highlight Blue Color Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pHlAlpha, [#comment: "Highlight Alpha Transparency:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pBevAngle, [#comment: "Bevel Angle:", #format: #integer, #default: 320, #range: [#min: 0, #max: 360]]
  addProp list, #pBevDist, [#comment: "Bevel Offset Distance:", #format: #integer, #default: 4, #range: [#min: -32, #max: 32]]
  addProp list, #pInner, [#comment: "Inner, Outer, or Full:", #format: #integer, #default: 1, #range: [#min: 0, #max: 2]]
  addProp list, #pKnockout, [#comment: "Knockout Effect:", #format: #boolean, #default: 0]
  return list
end

on mouseEnter me
  -- add Bevel VFX filter
  myFilter = filter(#BevelFilter, [#distance:pBevDist, #angle:pBevAngle, #highlightcolor:color(pHlColorR,pHlColorG,pHlColorB), #highlightAlpha:pHlAlpha, #shadowColor:color(pShadColorR,pShadColorG,pShadColorB), #shadowAlpha:pShadAlpha, #strength:pStrength, #quality:pQuality, #knockout:pKnockout, #inner:pInner])
  sprite(me.spriteNum).filterlist.append(myFilter)
end

on mouseLeave me
  -- clear VFX filter
  sprite(me.spriteNum).filterlist.deleteAll()
end