property pBlurX, pBlurY, pQuality, pStrength, pStrengthPcnt -- blur vars
property pR1, pG1, pB1, pR2, pG2, pB2 -- gradient colors
property pRatio1, pRatio2, pAlpha1, pAlpha2 -- ratio and alpha values
property pAngle -- shadow angle
property pDist -- shadow offset distance
property pKnockout, pInner

--
-- Drop onto a sprite for a Gradient Glow visual effect on mouseUp.
-- Works only with Director 11.5 or newer
-- Sprite must have 32-bit color for the effect to display.
-- Ken Loge - http://diginoodles.com
--

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pBlurX, [#comment: "Horizontal Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pBlurY, [#comment: "Vertical Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pQuality, [#comment: "Blur Quality:", #format: #integer, #default: 2, #range: [#min: 0, #max: 15]]
  addProp list, #pStrength, [#comment: "Imprint Strength:", #format: #integer, #default: 1, #range: [#min: 0, #max: 10]]
  addProp list, #pStrengthPcnt, [#comment: "Shadow Intensity:", #format: #integer, #default: 100, #range: [#min: 0, #max: 1000]]
  
  addProp list, #pR1, [#comment: "Red Start Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pG1, [#comment: "Green Start Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pB1, [#comment: "Blue Start Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pRatio1, [#comment: "Start Color Ratio Value:", #format: #integer, #default: 0, #range: [#min: 0, #max: 255]]
  addProp list, #pAlpha1, [#comment: "Alpha Start Value:", #format: #integer, #default: 0, #range: [#min: 0, #max: 255]]
  
  addProp list, #pR2, [#comment: "Red End Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pG2, [#comment: "Green End Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pB2, [#comment: "Blue End Value:", #format: #integer, #default: 0, #range: [#min: 0, #max: 255]]
  addProp list, #pRatio2, [#comment: "End Color Ratio Value:", #format: #integer, #default: 80, #range: [#min: 0, #max: 255]]
  addProp list, #pAlpha2, [#comment: "Alpha End Value:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  
  addProp list, #pAngle, [#comment: "Shadow Angle:", #format: #integer, #default: 336, #range: [#min: 0, #max: 360]]
  addProp list, #pDist, [#comment: "Shadow Glow Distance:", #format: #integer, #default: 4, #range: [#min: -32, #max: 32]]
  addProp list, #pInner, [#comment: "Outer, Inner, Full Shadow:", #format: #integer, #default: 0, #range: [#min: 0, #max: 2]]
  addProp list, #pKnockout, [#comment: "Knockout Effect:", #format: #boolean, #default: 0]
  return list
end

on mouseEnter me
  -- add VFX filter
  myFilter = filter(#GradientGlowFilter, [#distance:pDist, #angle:pAngle, #blurX:pBlurX, #blurY:pBlurY, #strength:pStrength, #strengthPercent:pStrengthPcnt, #quality:pQuality, #inner:pInner, #knockout:pKnockout, #colorList:[newColorRatio(color(pR1,pG1,pB1),pRatio1,pAlpha1), newColorRatio(color(pR2,pG2,pB2),pRatio2,pAlpha2)]])
  sprite(me.spriteNum).filterlist.append(myFilter)
end

on mouseLeave me
  -- clear VFX filter
  sprite(me.spriteNum).filterlist.deleteAll()
end