property pTextMemName -- the name of the text cast member to highlight
property pOrigFontSize -- the original font size
property pOrigFontColor -- the original font color
property pRedColorVal -- red color change value
property pGreenColorVal -- green color change value
property pBlueColorVal -- blue color change value
property pFontSizeInc -- font size increase

--------------------------------------------------------
-- Attach this to a text cast member.
--
-- This behavior allows a text member to temporarily
-- display a larger typeface size, with a new color,
-- then dispaly its original size and color.
--
-- Ken Loge - http://diginoodles.com
--------------------------------------------------------

on beginSprite me
  -- get the name of the text cast member
  pTextMemName = sprite(me.spriteNum).member.name
  -- store original values for later
  pOrigFontSize = member(pTextMemName).fontSize
  pOrigFontColor = member(pTextMemName).color
end

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pFontSizeInc, [#comment: "On rollover increase font size by:", #format: #integer, #default: "0", #range: [#min: 0, #max: 20]]
  addProp list, #pRedColorVal, [#comment: "Red color value on rollover:", #format: #integer, #default: 255, #range: [#min: 0, #max: 255]]
  addProp list, #pGreenColorVal, [#comment: "Green color value on rollover:", #format: #integer, #default: 0, #range: [#min: 0, #max: 255]]
  addProp list, #pBlueColorVal, [#comment: "Blue color value on rollover:", #format: #integer, #default: 0, #range: [#min: 0, #max: 255]]
  return list
end

-- change values
on mouseEnter me
  member(pTextMemName).fontSize = pOrigFontSize + pFontSizeInc
  member(pTextMemName).color = rgb(pRedColorVal, pGreenColorVal, pBlueColorVal)
  put
end

-- restore original values
on mouseLeave me
  member(pTextMemName).fontSize = pOrigFontSize
  member(pTextMemName).color = pOrigFontColor
end

on mouseUp me
  member(pTextMemName).fontSize = pOrigFontSize
  member(pTextMemName).color = pOrigFontColor
end

on mouseUpOutside me
  member(pTextMemName).fontSize = pOrigFontSize
  member(pTextMemName).color = pOrigFontColor
end