property pWidth -- the width of the vector box overlay sprite
property pXoffset -- the X offset in pixels for the overlay sprite
property pYoffset  -- the Y offset in pixels for the overlay sprite
property pWhichSprite -- the sprite channel of the overlay sprite
property pMemName -- the cast member name of the box overlay sprite

-- This behavior is designed for use with a vector shape that is sized to a 
-- width and height that is slightly larger than the text it is to surround.
-- v1.0 by Ken Loge - http://diginoodles.com

on beginSprite me
  -- compute half the width of the overlay sprite
  pWidth = sprite(pWhichSprite).width / 2
  -- get the member name of the overlay sprite
  pMemName = sprite(pWhichSprite).member.name
end

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pXoffset, [#comment: "X Offset for Overlay Box Sprite:", #format: #integer, #default: 4]
  addProp list, #pYoffset, [#comment: "Y Offset for Overlay Box Sprite:", #format: #integer, #default: 10]
  addProp list, #pWhichSprite, [#comment: "Overlay Box Sprite Channel:", #format: #integer, #default: 5] 
  return list
end

on mouseEnter me
  -- move the vector box to the rolled-over sprite, adjust position
  sprite(pWhichSprite).loc = sprite(me.spriteNum).loc + point(pWidth + pXoffset, pYoffset)
end

on mouseLeave me
  -- move vector box off screen
  sprite(pWhichSprite).loc = point(-1000,-1000)
  -- reset fill and blend
  member(pMemName).fillMode = #none
  sprite(pWhichSprite).blend = 100
end

on mouseDown me
  -- change fill and blend
  member(pMemName).fillMode = #solid
  sprite(pWhichSprite).blend = 40
end